XXXX国产在线播放_久久亚洲国产精品成人AV秋霞_日韩av无码精品人妻系列_国产一区二区精品久久小说_日韩无砖专区一中文字目

字串中文的問題

字串中文的問題，起於vb的字串是使用UniCode，而我們一般是使用Ascii Code。
這差別在何處呢？UniCode的每個字元長度是2個byte，而Ascii是一個byte，如果
說，我將們將VB的字串寫入檔案，有時會有意想不到的結(jié)果。例如：
  Text1.Text = "這是一個abc"
  len5 = Len(str5)
如果我們的Access資料庫有一欄位的長度是10個Byte，所以我們在TextBox中設(shè)定
MaxLength = 10，但是上面的例子得到的len5是7，而不是我們認為的11，因為不管
是中文或英文，vb一律以UniCode來存，所以str5的長度是7個"字元"，而text1最大
的長度限制是10，7沒有超過10，故使用者仍可輸入，但存檔時，11個byte超過10個
byte，所以會有錯。

可是或許有人發(fā)現(xiàn)，使用RS232來傳資料時，另一端主機是Ascii編碼的機器，在vb中
我們?nèi)羰褂肧tring來傳，一樣可以通啊，其實那是vb在傳送與接收data時，會做轉(zhuǎn)換
，使我們的程式設(shè)計較方便，但如果傳的資料是Binary時，就頭大啦。例如說，以字
串的方式來傳送資料，當想傳Ascii 大於128時，常有些問題，因為ASC(Chr(129))=0
，使我們不能用Chr()的指令來放資料。(事實上，您可以使用ChrW(129)來存資料，
和使用AscW()來取得值，加個W代表是Word的運算)，這時候，就只有使用Byte Array
來做了。

1.UniCode轉(zhuǎn)成ByteAry
  Dim byteAry() As Byte
  Dim str5 As String
  Dim i As Long
  str5 = "這abc"
  byteAry = str5
  For i = LBound(byteAry) To UBound(byteAry)
      Debug.Print byteAry(i)   '得 25 144 97 0 98 0 99 0
  Next i
  Debug.Print Len(str5), LenB(str5) '得4  8

  所以了，可看出UniCode 的特性，程式應(yīng)改一下，使用Strconv()來轉(zhuǎn)換

  Dim byteAry() As Byte
  Dim str5 As String
  Dim i As Long
  str5 = "這abc"
  byteAry = StrConv(str5, vbFromUnicode)
  For i = LBound(byteAry) To UBound(byteAry)
      Debug.Print byteAry(i)   '得 25 144 97 98 99
  Next i
  Debug.Print LenB(StrConv(str5, vbFromUnicode)) '得5

2.ByteAry轉(zhuǎn)回UniCode 使用Strconv()轉(zhuǎn)換
  Dim byteAry(10) as Byte
  Dim Str5 as String
  byteAry(0) = 25
  byteAry(1) = 144
  byteAry(2) = 97
  byteAry(3) = 98
  byteAry(4) = 99
  Str5 = StrConv(byteAry, vbUniCode)


3.一些有用的函式
SubStr()    中文化取子字串，相對Mid()
Strlen()    中文化字串長度，相對Len()
StrLeft()   中文化取左字串，相對Left()
StrRight()  中文化取右字串，相對Right()
isChinese() Check某個字是否中文字

Public Function SubStr(ByVal tstr As String, start As Integer, Optional leng As Variant) As String
Dim tmpstr  As String
If IsMissing(leng) Then
   tmpstr = StrConv(MidB(StrConv(tstr, vbFromUnicode), start), vbUnicode)
Else
   tmpstr = StrConv(MidB(StrConv(tstr, vbFromUnicode), start, leng), vbUnicode)
End If
SubStr = tmpstr
End Function

Public Function Strlen(ByVal tstr As String) As Integer
   Strlen = LenB(StrConv(tstr, vbFromUnicode))
End Function

Public Function StrLeft(ByVal str5 As String, ByVal len5 As Long) As String
Dim tmpstr As String
tmpstr = StrConv(str5, vbFromUnicode)
tmpstr = LeftB(tmpstr, len5)
StrLeft = StrConv(tmpstr, vbUnicode)
End Function

Public Function StrRight(ByVal str5 As String, ByVal len5 As Long) As String
Dim tmpstr As String
tmpstr = StrConv(str5, vbFromUnicode)
tmpstr = RightB(tmpstr, len5)
StrLeft = StrConv(tmpstr, vbUnicode)
End Function

Public Function isChinese(ByVal asciiv As Integer) As Boolean
   If Len(Hex$(asciiv)) > 2 Then
      isChinese = True
   Else
      isChinese = False
   End If
End Function

將阿拉伯數(shù)字轉(zhuǎn)成中文字的程式


               一個Form
               一個TextBox
               一個Label

  這個修訂後的程式是當使用者在TextBox中輸入只包含 0~9 的數(shù)值後，在Label中就可
  看見被轉(zhuǎn)換後的中文字，例如：1560890 轉(zhuǎn)成 "壹佰伍拾陸萬零捌佰玖拾"。程式限制
  為不可輸入超過16個數(shù)字。

  請建立一個新專案，并在表單中放入上述物件，再把以下程式碼復(fù)制到表單的程式
  碼視窗，最後按下F5來執(zhí)行。

  Private Sub Form_Load()
       Text1.MaxLength = 16
       Text1.Text = ""
       Label1.Caption = ""
       Label1.AutoSize = True
       Label1.BorderStyle = 1
  End Sub

  Private Sub Text1_Change()
       Label1.Caption = CChinese(Text1.Text)
  End Sub

  Private Function CChinese(StrEng As String) As String
       If Not IsNumeric(StrEng) Or StrEng Like "*.*" Or StrEng Like "*-*" Then
            If Trim(StrEng) <> "" Then MsgBox "無效的數(shù)字"
            CChinese = "": Exit Function
       End If
       Dim intLen As Integer, intCounter As Integer
       Dim strCh As String, strTempCh As String
       Dim strSeqCh1 As String, strSeqCh2 As String
       Dim strEng2Ch As String
       strEng2Ch = "零壹貳叁肆伍陸柒捌玖"
       strSeqCh1 = " 拾佰仟 拾佰仟 拾佰仟 拾佰仟"
       strSeqCh2 = " 萬億兆"
       StrEng = CStr(CDec(StrEng))
       intLen = Len(StrEng)
       For intCounter = 1 To intLen
            strTempCh = Mid(strEng2Ch, Val(Mid(StrEng, intCounter, 1)) + 1, 1)
            If strTempCh = "零" And intLen <> 1 Then
                 If Mid(StrEng, intCounter + 1, 1) = "0" Or (intLen - intCounter + 1) Mod 4 = 1 Then
                      strTempCh = ""
                 End If
            Else
                 strTempCh = strTempCh & Trim(Mid(strSeqCh1, intLen - intCounter + 1, 1))
            End If
            If (intLen - intCounter + 1) Mod 4 = 1 Then
                 strTempCh = strTempCh & Mid(strSeqCh2, (intLen - intCounter + 1) \ 4 + 1, 1)
                 If intCounter > 3 Then
                      If Mid(StrEng, intCounter - 3, 4) = "0000" Then strTempCh = Left(strTempCh, Len(strTempCh) - 1)
                End If
            End If
            strCh = strCh & Trim(strTempCh)
       Next
       CChinese = strCh
  End Function